Office Excel: Zeichen zählen - so geht's
Dank der Formel LÄNGE können Sie in Excel-Tabellen ganz einfach Zeichen zählen. Ganz egal, ob das nur in einer bestimmten Zelle geschehen soll oder für einen Bereich. Im Folgenden erklären wir Ihnen, wie Sie die Formel zum Zeichenzählen richtig anwenden.
Sie können hier für weitere Tipps zu Steuerelementen und Formeln in Excel weiterlesen.
- Gesamtzahl der Zeichen in einer Zelle zählen
- Spezifische Zeichen in einer Zelle zählen
- Gesamtzahl der Zeichen in einem Bereich zählen
- Spezifische Zeichen in einem Bereich zählen
Gesamtzahl der Zeichen in einer Zelle zählen
Gesamtzeichen in einer Zelle können mit der Excel-Funktion LÄNGE leicht gefunden werden. Diese Funktion hat hier nur ein Argument (Zellbezug oder Text), bei dem die Gesamtzahl der Zeichen gezählt werden soll:
=LÄNGE(Text)
=LÄNGE(D2)
Diese Funktion zählt die Gesamtzahl der Zeichen in einer Zelle, einschließlich Leerzeichen, Interpunktionszeichen und Symbolen, unabhängig davon, wie oft sie in einer Zeichenfolge vorkommen.
Spezifische Zeichen in einer Zelle zählen
Neben der Gesamtzahl der Zeichen gibt es in Excel auch die Möglichkeit, die Anzahl der Vorkommnisse bestimmter Zeichen zu zählen. Gehen wir das Beispiel der Zählung der Anzahl einzelner Zeichen in einer bestimmten Zelle durch. Zu diesem Zweck ist eine Kombination aus der LÄNGE- und WECHSELN-Funktion erforderlich. Die Formelsyntax wird also wie folgt aussehen:
=LÄNGE(Zelle)-LÄNGE(WECHSELN(Zelle;"Zeichen";""))
Wenn wir in einem bestimmten Beispiel die Anzahl der Zeichen a in einer definierten Zelle D2 zählen wollen, sieht die Formel wie folgt aus:
=LÄNGE(D2)-LÄNGE(WECHSELN(D2; "a";""))
Wir erklären kurz die Logik der Funktionskombination. Die gesamte Zeichenanzahl in einer Zelle D2 wird mit der Zeichenanzahl in derselben Zelle subtrahiert, aber ohne das spezifische Zeichen, das wir zählen wollen. Die Funktion WECHSELN wird hier verwendet, um eine Zeichenfolge in einer definierten Zelle in der Form ohne spezifisches Zeichen zu ändern und dieses Zeichen durch eine leere Zeichenfolge zu ersetzen.
=WECHSELN(Zelle; "Zeichen";"")
Im Endergebnis ist zu erkennen, dass die Funktion Großbuchstaben nicht zählt, da die LÄNGE-Funktion Groß- und Kleinschreibung berücksichtigt. Die Lösung für das Zählen von Zeichen ohne Berücksichtigung der Groß-/Kleinschreibung ist die Verwendung der Funktionen GROSS/KLEIN, bei der alle Zeichen in Groß-/Kleinschreibung übersetzt werden und die Funktion die Groß-/Kleinschreibung nicht mehr berücksichtigt.
Im Beispiel unten ist die Funktion KLEIN in die Funktion WECHSELN verschachtelt, wobei alle Zeichenfolgen in Zelle D2 in Kleinbuchstaben umgewandelt werden, da die Kriterien als Kleinbuchstaben "a" definiert sind:
=LÄNGE(Zelle)-LÄNGE(WECHSELN(KLEIN(Zelle); "Kleinbuchstabe";""))
=LÄNGE(D2)-LÄNGE(WECHSELN(KLEIN(D2); "a";""))
Gesamtzahl der Zeichen in einem Bereich zählen
Zum Zählen der Gesamtzeichenzahl in einem definierten Bereich ist die Kombination von zwei Funktionen erforderlich, SUMMENPRODUKT und LÄNGE. Die Verwendung der Funktion SUMMENPRODUKT ist eine elegante Lösung, wenn wir es mit mehreren Zellen oder Arrays zu tun haben. Sehen Sie sich das folgende Beispiel und eine Kombination der Formeln an:
=SUMMENPRODUKT(LÄNGE(Bereich))
=SUMMENPRODUKT(LÄNGE(D2:D4))
Die LÄNGE-Funktion ist auf die Zelle bezogen, aber für Zellbereiche ist die Verwendung von summierten LÄNGE-Funktionen (=LÄNGE(B3)+LÄNGE(B4)+LÄNGE(B5)+LÄNGE(B6)) nicht die beste Lösung, da Sie es mit großen Bereichen zu tun haben könnten. Stattdessen fasst die Funktion SUMMENPRODUKT die Ergebnisse der LÄNGE-Funktion in dem definierten Bereich zusammen. Bei der Formelauswertung sieht das Ergebnis wie folgt aus:
=SUMMENPRODUKT({16;42;36})
Bei den Zahlen aus dem Array handelt es sich um LÄNGE-Funktionsergebnisse aus jeder Zelle im definierten Bereich D2:D4, was ein Endergebnis von 94 Zeichen ergibt.
Spezifische Zeichen in einem Bereich zählen
Wie schon vorher erwähnt, ist die SUMMENPRODUKT-Funktion in Kombination mit anderen Funktionen erforderlich, um Zeichen in einem Bereich zu zählen. Für die Zählung des spezifischen Zeichens in einem Bereich, unter Berücksichtigung der Groß- und Kleinschreibung, wird die Kombination von drei Funktionen verwendet: SUMMENPRODUKT, LÄNGE und WECHSELN. Für das Zählen ohne Berücksichtigung der Groß- und Kleinschreibung sollten zusätzliche Formeln hinzugefügt werden: GROSS/KLEIN.
Zunächst erläutern wir das Zählen der Anzahl des Auftretens des Zeichens "a" in einem definierten Bereich (Version mit Berücksichtigung der Groß-/Kleinschreibung). Dies ist fast so ähnlich wie das Zählen spezifischer Zeichen in einer Zelle. Der Unterschied ergibt sich hier jedoch aus der LÄNGE-Funktion, die in der SUMMENPRODUKT-Funktion und im Zählbereich verschachtelt ist, statt der Zelle ist ein definierter Bereich von Zellen definiert:
=SUMMENPRODUKT(LÄNGE(D2:D4))-SUMMENPRODUKT(LÄNGE(WECHSELN(D2:D4;"a";"")))
Für die Zählung von Zeichen ohne Berücksichtigung der Groß-/Kleinschreibung in einem definierten Bereich können wir die ausführlich erläuterte Funktion für die Zählung von Zeichen in einer Zelle verwenden, jedoch mit zwei Änderungen: Verschachtelung der Funktion LÄNGE in der Funktion SUMMENPRODUKT und Ersetzen der Zelle durch den Zellbereich:
=SUMMENPRODUKT(LÄNGE(D2:D4))-SUMMENPRODUKT(LÄNGE(WECHSELN(WECHSELN(D2:D4;KLEIN("a");"");GROSS("a");"")))